Premiers pas avec les bases de données Public Cloud

Étape 1 : Rassemblez l'ensemble des paramètres requis

Pour créer un service de base de données, spécifiez au minimum :

• un moteur et sa version (par exemple MongoDB 8.0)
• le plan (par exemple production)
• les nœuds du cluster (par exemple 3 nœuds avec 4 cœurs, 15 Gio de mémoire, 100 Gio de disque)

Lister les fonctionnalités

L'endpoint capabilities liste les valeurs autorisées pour le moteur, le plan et le flavor.

L'appel renvoie un objet listant les moteurs autorisés (avec leurs versions), les plans et les flavors.

Obtenir la disponibilité

L'endpoint availability liste les combinaisons de paramètres valides. Chaque entrée liste un moteur, une version, un plan, un flavor, une région, le support du réseau public/privé et le nombre minimum/maximum de nœuds. Choisissez la combinaison qui correspond le mieux à vos besoins.

Étape 2 : Créez un service de base de données MongoDB

• description : une description lisible par un humain pour le service.
• plan : le plan souhaité.
• version : la version de MongoDB.
• nodesPattern : spécifiez le flavor, la région et le nombre de nœuds.
• nodeslist : laissez non défini — utilisez plutôt nodesPattern pour des clusters de même région et de même flavor.
• ipRestrictions : les plages d'adresses IP autorisées à se connecter.

Pour le réseau privé, spécifiez également networkId (ID du vRack) et subnetId (ID du sous-réseau du vRack).

L'appel renvoie l'objet du cluster. Son status est CREATING. Notez l'id pour l'étape suivante.

Étape 3 : Attendez que votre service de base de données soit prêt

Le cluster met quelques minutes à devenir utilisable. Vérifiez son statut à l'aide de :

Son status passe à READY lorsque le cluster est disponible.

Étape 4 : Réinitialisez le mot de passe de l'utilisateur principal

Listez les utilisateurs de votre cluster pour obtenir l'ID de l'utilisateur admin :

Réinitialisez le mot de passe de l'utilisateur admin :

Notez le nouveau mot de passe pour vous connecter au cluster.

Étape 5 : Commencez à utiliser le cluster

Les informations de connexion au cluster sont disponibles dans votre espace client OVHcloud. Vous pouvez désormais utiliser le cluster.

Étape 1 : Rassemblez l'ensemble des paramètres requis

Listez les moteurs, plans et flavors de nœuds disponibles :

ovhcloud cloud reference managed-database list-engines --cloud-project <projectId>
ovhcloud cloud reference managed-database list-plans --cloud-project <projectId>
ovhcloud cloud reference managed-database list-node-flavors --cloud-project <projectId>

Étape 2 : Créez un service de base de données MongoDB

ovhcloud cloud managed-database create \
  --cloud-project <projectId> \
  --engine mongodb \
  --version 8.0 \
  --plan production \
  --nodes-pattern.flavor db1-4 \
  --nodes-pattern.region GRA \
  --nodes-pattern.number 3 \
  --description "My MongoDB cluster" \
  --ip-restrictions "203.0.113.0/24"

Pour le réseau privé, ajoutez --network-id <networkId> et --subnet-id <subnetId>.

Étape 3 : Attendez que votre service de base de données soit prêt

ovhcloud cloud managed-database get <clusterId> --cloud-project <projectId>

Son status passe à READY lorsque le cluster est disponible.

Étape 4 : Réinitialisez le mot de passe de l'utilisateur principal

# Liste les utilisateurs et récupère l'ID de l'utilisateur admin
ovhcloud cloud managed-database user list <clusterId> --cloud-project <projectId>

# Réinitialise le mot de passe de l'utilisateur admin
ovhcloud cloud managed-database user credentials-reset <clusterId> <userId> --cloud-project <projectId>

Étape 5 : Commencez à utiliser le cluster

Les informations de connexion au cluster sont disponibles dans votre espace client OVHcloud. Vous pouvez désormais utiliser le cluster.

Étape 1 : Rassemblez les paramètres requis par OVHcloud

Le fournisseur Terraform OVHcloud nécessite les identifiants suivants :

• une application_key
• un application_secret
• une consumer_key

Pour les récupérer, suivez le guide Premiers pas avec les API OVHcloud. Générez des identifiants avec les droits suivants :

• GET /cloud/project/*/database/*

• POST /cloud/project/*/database/*

• PUT /cloud/project/*/database/*

• DELETE /cloud/project/*/database/*

• Générer des tokens API OVHcloud

Le service_name correspond à l'ID de votre projet Public Cloud. Récupérez-le via le bouton Copier dans le presse-papiers dans la section Public Cloud.

Étape 2 : Rassemblez l'ensemble des paramètres requis

Pour créer un nouveau cluster MongoDB, spécifiez au minimum :

• le moteur (par exemple mongodb)
• la version (par exemple 8.2)
• la région (par exemple EU-WEST-PAR)
• le plan (par exemple production)
• le flavor (par exemple b3-8)

Étape 3 : Créez les fichiers Terraform

Créez un fichier main.tf :

terraform {
  required_providers {
    ovh = {
      source  = "ovh/ovh"
      version = ">= 2.11.0"
    }
  }
}

provider "ovh" {
  endpoint           = var.ovh.endpoint
  application_key    = var.ovh.application_key
  application_secret = var.ovh.application_secret
  consumer_key       = var.ovh.consumer_key
}

resource "ovh_cloud_project_database" "service" {
  service_name = var.product.project_id
  description  = var.product.name
  engine       = var.product.engine
  version      = var.product.version
  plan         = var.product.plan
  nodes {
    region = var.product.region
  }
  nodes {
    region = var.product.region
  }
  nodes {
    region = var.product.region
  }
  flavor = var.product.flavor
  ip_restrictions {
    ip = var.product.ip
  }
}

resource "ovh_cloud_project_database_mongodb_user" "dbuser" {
  service_name = ovh_cloud_project_database.service.service_name
  cluster_id   = ovh_cloud_project_database.service.id
  name         = var.access.name
}

Créez un fichier variables.tf :

variable "ovh" {
  type = map(string)
  default = {
    endpoint           = "ovh-eu"
    application_key    = ""
    application_secret = ""
    consumer_key       = ""
  }
}

variable "product" {
  type = map(string)
  default = {
    project_id = ""
    name       = ""
    engine     = ""
    region     = "EU-WEST-PAR"
    plan       = "production"
    flavor     = "b3-8"
    version    = ""
    ip         = "0.0.0.0/32"
  }
}

variable "access" {
  type = map(string)
  default = {
    name = "johndoe"
  }
}

Utilisez ovh-eu pour l'API OVHcloud Europe, ou ovh-ca pour l'Amérique du Nord.

Créez un fichier secrets.tfvars avec vos valeurs réelles :

ovh = {
  endpoint           = "ovh-eu"
  application_key    = "<application_key>"
  application_secret = "<application_secret>"
  consumer_key       = "<consumer_key>"
}

product = {
  project_id = "<service_name>"
  name       = "mongodb-terraform"
  engine     = "mongodb"
  region     = "EU-WEST-PAR"
  plan       = "production"
  flavor     = "b3-8"
  version    = "8.2"
  ip         = "<ip_range>"
}

access = {
  name = "johndoe"
}

Créez un fichier outputs.tf :

output "cluster_uri" {
  value = ovh_cloud_project_database.service.endpoints.0.uri
}

output "user_name" {
  value = ovh_cloud_project_database_mongodb_user.dbuser.name
}

output "user_password" {
  value     = ovh_cloud_project_database_mongodb_user.dbuser.password
  sensitive = true
}

Étape 4 : Exécutez

terraform init
terraform plan -var-file=secrets.tfvars
terraform apply -var-file=secrets.tfvars -auto-approve

Exportez les identifiants et l'URI :

export PASSWORD=$(terraform output -raw user_password)
export USER=$(terraform output -raw user_name)
export URI=$(terraform output -raw cluster_uri)

Votre cluster MongoDB est maintenant prêt.

Des exemples pour d'autres moteurs (MySQL, PostgreSQL) sont disponibles dans le dépôt public-cloud-databases-examples.